class Shape {

  Hair[] tuft = null;

  RShape illustration;

  int numPoints = 100;

  Shape(PApplet p) {

    RG.init(p);
    RG.ignoreStyles(true);

    illustration = RG.loadShape("twothousandnine.svg");
    illustration = RG.centerIn(illustration, g, 50); 

    int child_count = illustration.children[0].countChildren();
    for(int i=0; i<child_count; i++) {
      
      RPolygon poly = (RPolygon)(illustration.children[0].children[i].toPolygon());
      poly = poly.update();

      for(int j=0; j<poly.countContours(); j++) {

        RContour contour = poly.contours[j];
        if (contour.isHole()) continue;

        RPolygon subpoly = new RPolygon(contour);
        RShape subshape = subpoly.toShape();

        for(int k=0; k<numPoints; k++) {
          
          RPoint pt = subshape.getPoint(float(k)/float(numPoints));
          RPoint tangent = subshape.getTangent(float(k)/float(numPoints));

          float angle = atan2( tangent.y, tangent.x );

          appendHair(pt, angle);
        }
      }
    }

  }

  void appendHair(RPoint pt, float angle) {

    if (tuft == null) {
      tuft = new Hair[1];
      tuft[0] = new Hair(pt,angle); 
    } 
    else {
      tuft = (Hair[])append(tuft, new Hair(pt,angle));
    }

  }

  void draw() {

    translate(width/2, height/2);
    
    noStroke();
    fill(0);
    //illustration.draw();

    for(int i=0; i<tuft.length; i++) {
      tuft[i].draw(); 
    }

  }

}